'On Input' Window Event Simulation in Dialogs
 by Soul_Eater ©2002


This tutorial was designed to explain how to simulate the 'on input' @window event
in a dialog. A prime example of this would be the 'arnie' easter egg in the
About mIRC dialog box.

Let's begin. First off, you will want to choose the word or text you want to be inputted.
For example purposes, we will use 'arnie'.

Next, create a dialog, and call it whatever you want. Now this is the important part:
Create a button with the ampersand(&) prefixing the first letter of your word. As you can
see below, '&a' would be done in "arnie" 's case. Then, make the button hidden by adding the
'hide' style. After you have completed your dialog, you will need to add the event for the 
button sclick(show below). After each sclick, you have to check what the letter is, then reset
it to the next letter in the word, and halt the event. This must be done all the way down
until your last letter is pressed. When your last letter is pressed, reset the button to the
first letter, then add your desired command(s)! When you type 'arnie' into the dialog below,
it displays some text, when you type 'arnie' again, it disappears. This could be used for
script easter eggs or other miscellaneous functions. Good luck!

Example Code:


;Example Dialog Input Script
;by Soul_Eater
dialog example {
  title "Example Dialog Input Script"
  icon $mircexe,11
  size -1 1 250 100
  button "",1, 0 0 0 0,cancel
  button "&a",2, 10 10 50 50,hide
  ;This is our input tracking button, make sure it is hidden.
  text "",3, 50 30 100 20
  menu "Type arnie",4
}
;the word 'arnie' is our input here
;You must make sure each letter has an ampersand(&) in front of it, thats what 'sclicks' it
;This is where we do the actual 'on input' commands. You check to see if the id text is a letter
;in the word, and if it is, you reset it to the next letter, etc until the final letter where
;you choose your commands
on *:dialog:example:sclick:2:{
  ;if you don't halt after each input, it goes straight to the final letter
  if ($did($did) == &a) { did -ra $dname $did &r | halt }
  ;after each input you have to reset the id text to the next letter in the word,dont forget the &
  if ($did($did) == &r) { did -ra $dname $did &n | halt }
  if ($did($did) == &n) { did -ra $dname $did &i | halt }
  if ($did($did) == &i) { did -ra $dname $did &e | halt }
  if ($did($did) == &e) { 
    var %x = this is a test
    if ($did(3) == %x) { did -ra $dname $did &a | did -r $dname 3 | halt }
    else { did -ra $dname $did &a | did -ra $dname 3 %x | halt }
  }
}